PJblog 防止广告机添加-加法验证码

效果见本站
第一步:打开common/GetCode.asp 全部清空,然后输入以下代码,上传到common/中

程序代码
程序代码 程序代码
<%@CodePage="65001"%>
<%
Call Com_CreatValidCode("GetCode")

Sub Com_CreatValidCode(pSN)
    ' 禁止缓存
    Response.Expires = -9999
    Response.AddHeader "Pragma","no-cache"
    Response.AddHeader "cache-ctrol","no-cache"
    'Response.ContentType = "Image/BMP"

    Randomize

    Dim i, ii, iii

    Const cOdds = 4 ' 杂点出现的机率
    Const cAmount = 13 ' 文字数量
    Const cCode = "0123456789+=?"

    ' 颜色的数据(字符,背景)
    Dim vColorData(1),vColorRandom(10)
    'vColorData(0) = ChrB(Int(Rnd*155)+100) & ChrB(Int(Rnd*155)+100) & ChrB(Int(Rnd*155)+100) ' 蓝0,绿0,红0(黑色)
    vColorRandom(0)=ChrB(150) & ChrB(0) & ChrB(0)
    vColorRandom(1)=ChrB(0) & ChrB(150) & ChrB(0)
    vColorRandom(2)=ChrB(0) & ChrB(0) & ChrB(150)
    vColorRandom(3)=ChrB(0) & ChrB(50) & ChrB(150)
    vColorRandom(4)=ChrB(150) & ChrB(50) & ChrB(0)
    vColorRandom(5)=ChrB(150) & ChrB(0) & ChrB(150)
    vColorRandom(6)=ChrB(150) & ChrB(100) & ChrB(10)
    vColorRandom(7)=ChrB(150) & ChrB(40) & ChrB(120)
    vColorRandom(8)=ChrB(150) & ChrB(0) & ChrB(250)
    vColorRandom(9)=ChrB(100) & ChrB(100) & ChrB(100)
    vColorRandom(10)=ChrB(50) & ChrB(50) & ChrB(50)
    vColorData(0) = vColorRandom(0)
    vColorData(1) = ChrB(250) & ChrB(250) & ChrB(255) '背景色 蓝250,绿236,红211(浅蓝色)
    ' 随机产生字符
    Dim vCode(6),vCodes,vCodeColors(6)
    For i = 0 To 6
        vCodeColors(i)=vColorRandom(Int(Rnd * 10))
    Next
    
    vCode(0) = Int(Rnd*8)+1
    vCode(1) = Int(Rnd*9)
    vCode(2) = 10
    vCode(3) = Int(Rnd*8)+1
    vCode(4) = Int(Rnd*9)
    vCode(5) = 11
    vCode(6) = 12
    Session(pSN) = vCode(0)*10+vCode(1)+vCode(3)*10+vCode(4) '记录入Session
    ' 字符的数据
    Dim vNumberData(12)
    vNumberData(0) = "1110000111110111101111011110111101001011110100101111010010111101001011110111101111011110111110000111"
    vNumberData(1) = "1111011111110001111111110111111111011111111101111111110111111111011111111101111111110111111100000111"
    vNumberData(2) = "1110000111110111101111011110111111111011111111011111111011111111011111111011111111011110111100000011"
    vNumberData(3) = "1110000111110111101111011110111111110111111100111111111101111111111011110111101111011110111110000111"
    vNumberData(4) = "1111101111111110111111110011111110101111110110111111011011111100000011111110111111111011111111000011"
    vNumberData(5) = "1100000011110111111111011111111101000111110011101111111110111111111011110111101111011110111110000111"
    vNumberData(6) = "1111000111111011101111011111111101111111110100011111001110111101111011110111101111011110111110000111"
    vNumberData(7) = "1100000011110111011111011101111111101111111110111111110111111111011111111101111111110111111111011111"
    vNumberData(8) = "1110000111110111101111011110111101111011111000011111101101111101111011110111101111011110111110000111"
    vNumberData(9) = "1110001111110111011111011110111101111011110111001111100010111111111011111111101111011101111110001111"
    vNumberData(10) = "1111111111111101111111110111111111011111100000001111110111111111011111111101111111110111111111111111"
    vNumberData(11) = "1111111111111111111111111111111000000001111111111111111111111000000001111111111111111111111111111111"
    vNumberData(12) = "1110000111110011001111011110111111111011111111001111111001111111001111111111111111110011111111001111"
    
    ' 输出图像文件头
    Response.BinaryWrite ChrB(66) & ChrB(77) & ChrB(166) & ChrB(8) & ChrB(0) & ChrB(0) & ChrB(0) & ChrB(0) &_
    ChrB(0) & ChrB(0) & ChrB(54) & ChrB(0) & ChrB(0) & ChrB(0) & ChrB(40) & ChrB(0) &_
    ChrB(0) & ChrB(0) & ChrB(72) & ChrB(0) & ChrB(0) & ChrB(0) & ChrB(10) & ChrB(0) &_
    ChrB(0) & ChrB(0) & ChrB(1) & ChrB(0)

    ' 输出图像信息头
    Response.BinaryWrite ChrB(24) & ChrB(0) & ChrB(0) & ChrB(0) & ChrB(0) & ChrB(0) & ChrB(112) & ChrB(8) &_
    ChrB(0) & ChrB(0) & ChrB(18) & ChrB(11) & ChrB(0) & ChrB(0) & ChrB(18) & ChrB(11) &_
    ChrB(0) & ChrB(0) & ChrB(0) & ChrB(0) & ChrB(0) & ChrB(0) & ChrB(0) & ChrB(0) &_
    ChrB(0) & ChrB(0)
    For i = 9 To 0 Step -1 ' 历经所有行
        For ii = 0 To 6 ' 历经所有字
            For iii = 1 To 10 ' 历经所有像素
                ' 逐行、逐字、逐像素地输出图像数据
                vColorData(0)=vCodeColors(ii)
                If Rnd * 99 + 1 < cOdds Then ' 随机生成杂点
                    Response.BinaryWrite vColorData(0)
                Else
                    Response.BinaryWrite vColorData(Mid(vNumberData(vCode(ii)), i * 10 + iii, 1))
                End If
            Next
        Next
    Response.BinaryWrite vColorData(1) & vColorData(1)
    Next
End Sub

%>

第二步:common/function.asp 目的是为了表单对齐
找到:

程序代码
程序代码 程序代码
<img src=""common/getcode.asp"" alt="""" style=""margin-right:40px;""/>


把40改成8,就像下面这样

程序代码
程序代码 程序代码
<img src=""common/getcode.asp"" alt="""" style=""margin-right:8px;""/>

完成。
验证码bug修补
很难理解为什么会有那么多的广告机,而且即使验证码显示为空白照样会有很多广告。最后终于发现是因为PJBLOG存在严重外部提交漏洞。
漏洞成因:

引用内容
blogcomm.asp文件对验证码判断不严格。
如果用户没有请求过GetCode.asp文件,那么服务器端Session里面的GetCode值为空,而用户提交的数据里面验证码也为空,这样刚好空等于空,反而通过了验证码验证。

广告机javascrip版


引用内容
<script type="text/javascript">
var XMLHTTP, Param;
Param = "action=post&logID=114&username=" + encodeURI("我是广告机!") + "&Message=" + encodeURI("我是广告机!");
XMLHTTP = new ActiveXObject("Msxml2.XMLHTTP");
XMLHTTP.open("POST", "http://localhost/blog/blogcomm.asp", false); // 这里的localhost为攻击对象
XMLHTTP.setRequestHeader("Content-Length", Param.length);
XMLHTTP.setRequestHeader("Content-Type", "application/x-www-form-urlencoded");
XMLHTTP.send(Param);
</script>
这样就可以绕过验证码从外部提交表单,散播广告。

修正bug方法:
修改blogcomm.asp文件,在94行

程序代码
IF (memName=empty or blog_validate=true) and cstr(lcase(Session("GetCode")))<>cstr(lcase(validate)) then
改成


程序代码
IF (memName=empty or blog_validate=true) and (cstr(lcase(Session("GetCode")))<>cstr(lcase(validate)) or IsEmpty(Session("GetCode"))) then

还有几中方法
pjhome.net" target="_blank">pjhome.net" target="_blank">pjhome.net" target="_blank">pjhome.net" target="_blank">pjhome.net" target="_blank">PJBlog验证码--加法验证码和问题验证码
程序代码 程序代码
在common/function.asp中找到相应的位置,替换成以下代码:

'加法验证码开始
Function getcode()

Dim QuesionNum
QuesionNum=10  '控制计算数的位数,此数必须大于10,不然全为0.如果想一位数相加,请用10,两位数相加,请用100,混合位数相加,11~99.其它类推

Dim Num1
Dim Num2
Dim Dis_Num
Dim Sum

Randomize
Num1 = Int(QuesionNum * Rnd)
Num2 =  Int(QuesionNum * Rnd)
Dis_Num = "=" & Num1 & "+" & Num2
Sum = Num1 + Num2
Session("GetCode") = Sum
getcode = "<span style=""margin-right:40px;"">" & Dis_Num & "</span>"
End Function
'加法验证码结束

'问题验证码开始
Function getcode()

Dim QuesionNum
QuesionNum=10  '问题的总数,如要添加问题,请先修改这个数值
Dim CodeIndex
CodeIndex=0

Dim QuesionArray(100)
Dim AnswerArray(100)

'问题列表及答案,可自行修改
QuesionArray(0)="请输入<font color=red>x</font>uanzsheng中的第一个字母:x"
AnswerArray(0)="x"
QuesionArray(1)="请输入x<font color=red>u</font>anzsheng中的第二个字母:u"
AnswerArray(1)="u"
QuesionArray(2)="请输入xu<font color=red>a</font>nzsheng中的第三个字母:a"
AnswerArray(2)="a"
QuesionArray(3)="请输入xua<font color=red>n</font>zsheng中的第四个字母:n"
AnswerArray(3)="n"
QuesionArray(4)="请输入xuan<font color=red>z</font>sheng中的第五个字母:z"
AnswerArray(4)="z"
QuesionArray(5)="请输入xuanz<font color=red>s</font>heng中的第六个字母:s"
AnswerArray(5)="s"
QuesionArray(6)="请输入xuanzs<font color=red>h</font>eng中的第七个字母:h"
AnswerArray(6)="h"
QuesionArray(7)="请输入xuanzsh<font color=red>e</font>ng中的第八个字母:e"
AnswerArray(7)="e"
QuesionArray(8)="请输入xuanzshe<font color=red>n</font>g中的第九个字母:n"
AnswerArray(8)="n"
QuesionArray(9)="请输入xuanzshen<font color=red>g</font>中的第十个字母:g"
AnswerArray(9)="g"

Randomize
CodeIndex =  Int((QuesionNum * Rnd) + 0)
Session("GetCode") = AnswerArray(CodeIndex)
getcode = "<span style=""margin-right:40px;"">" & QuesionArray(CodeIndex) & "</span>"
End Function
'问题验证码结束


需要的朋友赶紧修改下吧!

文章来自: 本站原创
引用通告: 查看所有引用 | 我要引用此文章
Tags:
评论: 84 | 引用: 0 | 查看次数: 9847
虽然发表评论不用注册,但是为了保护您的发言权,建议您注册帐号.
字数限制 1000 字 | UBB代码 关闭 | [img]标签 关闭